Subversion Repositories SmartDukaan

buildscript {

    ext {

        springBootVersion = '2.0.2.RELEASE'

    }

    repositories {

        mavenCentral()

    }

    dependencies {

        classpath("org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}")

    }

}

apply plugin: 'java'

apply plugin: 'eclipse'

apply plugin: 'org.springframework.boot'

apply plugin: 'io.spring.dependency-management'

group = 'com.smartdukaan'

version = '0.0.1-SNAPSHOT'

sourceCompatibility = 1.8

ext['log4j2.version'] = '2.16.0'

repositories {

    maven { url "https://repo.maven.apache.org/maven2" }

    maven { url 'https://jitpack.io' }

    mavenLocal()

}

task run {

    Set environments = ["dev", "staging", "prod"]

    def environment = "dev"

    if (project.hasProperty("env")) {

        if (environments.contains(project.getProperty("env"))) {

            environment = project.getProperty("env");

        } else {

            logger.warn("Invalid Environment value, Choose any 'dev', 'staging', 'prod'");

            logger.info("Environment set to dev");

        }

    } else {

        logger.info("Environment set to dev");

    }

    ant.propertyfile(file: "src/main/resources/META-INF/env.property") {

        entry(key: "profile", value: environment)

    }

    logger.info("Build is being built by " + environment)

}

tasks.build.doLast() {

    ant.propertyfile(file: "src/main/resources/META-INF/env.property") {

        entry(key: "profile", value: "dev")

    }

}

dependencies {

    compile('org.springframework.boot:spring-boot-starter') {

        exclude(module: 'logback-classic')

        exclude(module: 'spring-boot-starter-logging')

    }

    implementation group: 'org.springframework', name: 'spring-context-support', version: '4.3.6.RELEASE'

    compile group: 'org.apache.velocity', name: 'velocity', version: '1.7'

    compile project(':profitmandi-common')

    compile project(':profitmandi-dao')

    // PDF table extraction for the Pine Labs affordability circular. Lives here and

    // NOT in profitmandi-common so PDFBox never reaches the web/fofo WARs - common

    // deliberately keeps pdfbox at test scope only.

    //   - bouncycastle is only for encrypted PDFs (ours are not) and its

    //     bcprov-jdk15on:1.69 would clash with bcprov-jdk16:1.45 already here

    //   - slf4j-simple would bind as a second SLF4J provider against log4j2

    //   - jai-imageio is image decoding; we read text and rulings only

    implementation('technology.tabula:tabula:1.0.5') {

        exclude group: 'org.bouncycastle'

        exclude group: 'org.slf4j', module: 'slf4j-simple'

        exclude group: 'com.github.jai-imageio'

    }

    compile 'com.fasterxml.jackson.module:jackson-module-parameter-names:2.9.6'

    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8:2.9.6:'

    compile 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.9.6'

    compile group: 'org.jsoup', name: 'jsoup', version: '1.11.3'

    compile group: 'org.seleniumhq.selenium', name: 'selenium-java', version: '2.41.0'

    implementation 'org.jsoup:jsoup:1.11.3'

    implementation 'org.apache.httpcomponents:httpclient:4.5.13'

    implementation 'org.bouncycastle:bcprov-jdk16:1.45'

    //dependency needed to resolve okhttp and further required for selenium

    implementation 'org.jetbrains.kotlin:kotlin-stdlib:1.8.0'

    // https://mvnrepository.com/artifact/opencv/opencv

    implementation group: 'org.openpnp', name: 'opencv', version: '3.4.2-0'

    implementation('com.google.auth:google-auth-library-oauth2-http:1.17.0') {

        exclude group: 'org.apache.httpcomponents', module: 'httpclient'

        exclude group: 'com.google.guava', module: 'guava'

    }

    dependencies {

        implementation 'org.jsoup:jsoup:1.18.1'

    }

    implementation('org.springframework.boot:spring-boot-starter-actuator') {

        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'

    }

    implementation('io.micrometer:micrometer-core') {

        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'

    }

    implementation('io.micrometer:micrometer-registry-prometheus') {

        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'

    }

    implementation 'org.springframework.boot:spring-boot-starter-log4j2'

    implementation('org.springframework.boot:spring-boot-starter-web') {

        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'

    }

    implementation 'org.aspectj:aspectjweaver'

    implementation ('org.springframework.boot:spring-boot-starter-security'){

        exclude group: 'org.springframework.boot', module: 'spring-boot-starter-logging'

    }

    // Add HikariCP dependency

    implementation 'com.zaxxer:HikariCP:3.4.5' // Use the latest version

    implementation 'net.lingala.zip4j:zip4j:2.11.5'

    testCompile 'junit:junit:4.13.2'

    testCompile 'org.mockito:mockito-core:3.12.4'

    // Force byte-buddy: Spring Boot BOM downgrades to 1.7.11 which is incompatible with Mockito 3.12.

    testCompile 'net.bytebuddy:byte-buddy:1.11.13'

    testCompile 'net.bytebuddy:byte-buddy-agent:1.11.13'

}

defaultTasks 'run', 'build'

// Writes the module's runtime classpath to build/circular-classpath.txt so the

// offer-circular ingest can be driven locally outside Spring - see

// scripts/offer_circular/README.md ("Running and measuring an ingest locally").

// Originally added to diff the port against the reference Python implementation;

// that Python is gone, but the harness it enabled is still how an ingest is

// reproduced and measured, so this task stays.

task dumpCircularClasspath {

    doLast {

        new File("$buildDir/circular-classpath.txt").text =

                sourceSets.main.runtimeClasspath.asPath

    }

}